Tekstfunksjonar

Denne bolken handlar om Tekst-funksjonane.

For Ă„ bruka denne funksjonen 


Set inn → Funksjon → Kategori Tekst


Bruk av doble hermeteikn i formlar

Skal du ha med ein tekststreng i ein formel, skriv du han mellom doble hermeteikn ("). Dette gjer at Calc tek med teksten i strengen utan Ä gjera noko meir med han. SÄleis vi formelen "Hallo verda" visa teksten Hallo verda i cella utan hermeteikna.

Den meir komplekse formelen =KJEDA.SAMAN("Livet er enkelt, "; "men vi insisterer pÄ Ä gjera det komplisert "; "(Konfutse).") vil kjeda saman dei tre enkeltstrengane i doble hermeteikn til Livet er enkelt, men vi insisterer pÄ Ä gjera det komplisert (Konfutse).

Skal du visa eit verkeleg dobbelthermeteikn i ein streng i ein formel, kan du gjera det pÄ to mÄtar:

  1. Du kan «Escape» det doble hermeteiknet med eit dobbelt hermeteikn, altsĂ„ setja eit dobbelt hermeteikn framfĂžre det doble hermeteiknet. Calc vil dĂ„ handsama det ekstra hermeteiknet som eit hermeteikn. SĂ„leis vil formelen="Namnet mitt er ""Ole Olsen""." gje strengen Namnet mitt er "Ole Olsen". Eit anna enkelt eksempel er formelen =UNICODE("""") som returnerer 34, desimalverdien av hermeteiknet i Unicode (U+0022) – her viser det det fĂžrste og det fjerde doble hermeteiknet byrjinga og slutten av strengen, medan det andre doble hermeteiknet «escapes» det tredje.

  2. Du kan bruka TEIKNKODE-funksjonen eller UNITEIKN-funksjonen for Ă„ setja inn eit dobbelt hermeteikn. For eksempel vil formelen =UNITEIKN(34) & "Redderen i rugen" & UNITEIKN(34) & " er ei kjent bok av J. D. Salinger." visa strengen "Redderen i rugen" er ei kjent bok av J. D. Salinger.

Ver merksam pĂ„ at autorettingsfunksjonen i Calc kan endra doble hermeteikn. Autorettinga skal ikkje endra dei doble hermeteikna i formelceller, men kan endra dei som vert brukte i celler som ikkje er formelceller og inneheld tekst. Viss du for eksempel kopierer ein streng som er omgjeve av ei anna form for typografiske doble hermeteikn, for eksempel venstre doble hermeteikn (U+201C) (“) og hĂžgre doble hermeteikn (U+201D) (”), og deretter limer inn i ei formelcelle, kan du fĂ„ ei feilmelding. Opna omrĂ„det Doble sitatteikn i VerktĂžy → Autoretting → Innstillingar for autoretting → Lokaliserte val for Ă„ bestemma kva teikna som skal brukast til Ă„ retta start- og slutttypografiske doble hermeteikn. Fjern avmerkinga for Erstatt for Ă„ slĂ„ av funksjonen.

ARABISK

Returnerer talverdien, som tekst, som svarar til eit romartal.

ASC

Konverterer dobbelt-byte (fullbreidde) teikn til enkelt-byte (halvbreidde) ASCII- og katakana-teikn.

JIS

Konverterer enkelt-byte (halv-breidde) ASCII- eller katakana-teikn til dobbelt-byte (fullbreidde) teikn.

REGEX

Finn og trekk ut eller bytar ut tekst ved hjelp av regulĂŠre uttrykk.

ROMARTAL

Konverterer eit tal til eit romartal. VerdiomrÄdet mÄ vera mellom 0 og 3999. Ein enklare modus kan brukast i omrÄdet frÄ 0 til 4.

VERDI

Konverterer strengrepresentasjonen av eit tal til numerisk form. Viss strengen er ein gyldig dato, klokkeslett eller dato-klokkeslett, vert det serielle dato-klokkeslett-talet returnert.

NETTENESTE

Hent innhald frÄ nettet via ein URI.

FILTERXML

Bruk eit XPath-uttrykk pÄ eit XML-dokument.

NETTADRESSEKODE

Returnerer ein streng med dekoda nettadresse.

BAHTTEKST (BAHTTEXT pÄ engelsk)

Gjer eit tal om til Thaitekst, inklusive Thaivalutanamn.

Syntaks

BAHTTEKST(Tal)

Tal er eit vilkÄrleg tal. «Baht» vert lagt til den heile delen av talet, og «Satang» vert lagt til desimaldelen av talet.

Eksempel

=BAHTTEKST(12,65) returnerer ein streng i Thaiteikn som omsett vert «Tolv Baht og sekstifem Satang».

Teknisk informasjon

Denne funksjonen er ikkje ein del av standarden Open Document Format for kontorprogram (OpenDocument) Versjon 1.3. del 4: Omrekna formel (OpenFormula)-format. Namnerommet er

COM.MICROSOFT.BAHTTEXT

BASE

Gjer om eit positivt heiltal til ein tekst i eit bestemt talsystem. Tala 0-9 og bokstavane A-Z vert brukte.

Syntaks

BASE(Tal; Grunntal[;Minimumslengd])

Tal er det positive heiltalet som skal konverterast.

Base indikerer basen for talsystemet. Det kan vara alle positive heiltal mellom 2 og 36.

Minimumlengd (valfri) bestemmer den minste lengda pÄ teiknsekvensen som skal lagast. Dersom teksten er kortare enn denne minstelengda, vert det lagt til nullar til venstre i strengen.

Eksempel

=BASIS(17; 10; 4) returnerer 0017 i det desimale talsystemet (titalssystemet).

=BASIS(17; 2) returnerer 10001 i det binĂŠre talsystemet.

=BASIS(255; 16; 4) returnerer 00FF i det heksadesimale talsystemet.

SjÄ ogsÄ

DESIMAL

BYT.UT (SUBSTITUTE pÄ engelsk)

Byter ut ein tekst med ein ny tekst i ein streng.

Syntaks

BYT.UT("Tekst"; "SĂžkjeTekst"; "NyTekst"[; FĂžrekomst])

Tekst er teksten der tekstsegmenta skal bytast ut.

SĂžkTekst er tekstsegmentet som skal byttast ut (fleire gongar).

NyTekst er teksten som skal erstatte tekstsegmentet.

FĂžrekomst (valfri) indikerer kva fĂžrekomst av sĂžkjeteksten som skal byttast ut. Dersom denne parameteren manglar, vert alle fĂžrekomstane bytt ut.

Eksempel

=BYT.UT("123123123";"3";"abc") returnerer 12abc12abc12abc

=BYT.UT("123123123";"3";"abc";2) returnerer 12312abc123

DESIMAL (DECIMAL pÄ engelsk)

Konverterer tekst med teikn frÄ eit talsystem til eit positivt heiltal med det gjevne grunntalsystemet. Grunntalet mÄ vera i omrÄdet 2 til 36. Mellomrom og tabuleringar vert ignorerte. Feltet Tekst skil ikkje mellom smÄ og store bokstavar.

Viss basen er 16 vert eit innleiande x eller X, 0x eller 0X eller avsluttande h eller H ignorerte. Viss basen er 2, vert avsluttande b eller B ignorert. Andre teikn som ikkje hĂžyrer til i talsystemet vil generera ein feil.

Syntaks

DESIMAL("Tekst"; Base)

Tekst er teksten som skal konverterast.

Base indikerer basen for talsystemet. Det kan vara alle positive heiltal mellom 2 og 36.

Eksempel

=DESIMAL("17"; 10) returnerer 17.

=DESIMAL("FACE"; 16) returnerer 64206.

=DESIMAL("0101"; 2) returnerer 5.

SjÄ ogsÄ

BASE

ERSTATT (REPLACE pÄ engelsk)

Byter ut ein del av ein tekststreng med ein annan. Kan brukast til Ä byta ut bÄde teikn og tal (tala vert automatisk gjorde om til tekst). Resultatet av denne funksjonen vert alltid vist som tekst. Om du vil gjera fleire utrekningar pÄ eit tal som er bytt ut med tekst, mÄ du gjera om teksten til eittal ved Ä bruka VERDI-funksjonen.

All tekst som inneheld tal mÄ vera i hermeteikn (") dersom du ikkje Þnskjer at han skal tolkast som tal og automatisk verta konvertert til tekst.

Syntaks

ERSTATT("Tekst"; Plassering; Lengd; "NyTekst")

Tekst er den teksten der ein del av innhaldet skal bytast ut.

Posisjon er startpunktet for utskiftinga.

Lengd er kor mange teikn i Tekst som skal bytast ut.

NyTekst er den teksten som skal bytast ut i Tekst.

Eksempel

ERSTATT("1234567"; 1; 1; "444") returnerer "444234567". Eitt teikn i posisjon 1 er erstatta av heile NyTekst.

FAST (FIXED pÄ engelsk)

Returnerer eit tal som tekst med eit bestemt tal pÄ desimalar og valfrie tusenskiljeteikn.

Syntaks

FAST(Tal; [Desimalar = 2[; IngenTusenskiljeteikn = USANN]])

Tal vert avrunda til Desimal desimalplassar (etter desimalskiljeteiknet) og resultatet vert formatert som tekst, med lokale innstillingar.

Desimalar (valfri) er kor mange desimalar som skal visast. VissDesimalar er negativ, vert Tal avrunda til ABS (Desimalar) (absolutte desimalar) til venstre for desimalteiknet. Viss Desimalar er ein brĂžk, vert berre heile talet brukt.

IngenTusenskilje (valfri) bestemmer om det skal brukast tusenskiljeteikn. Viss denne er sett til Sann eller eit anna tal enn null, vert tusenskileteiknet ikkje brukt i resultatstrengen. Viss parameteren er lik 0 eller manglar heilt, vert tusentalsskiljeteikna frÄ den aktuelle lokale innstillinga brukt.

Eksempel

=FAST(1234567,89;3) returnerer 1.234.567,890 som ein tekststreng.

=FAST(123456,789;;Sann) returnerer 123456,79 som ein tekststreng.

=FAST(12345,6789;-2) returnerer 12,300 som ein tekststreng.

=FAST(1234567,89;-3;1) returnerer 12135000 som ein tekststreng.

=FAST(12345,789;3/4) returnerer 12.346 som ein tekststreng.

=FAST(12345,789;5/4) returnerer 12 345,8 som ein tekststreng.

FINN (FIND pÄ engelsk)

Returnerer plasseringa av ein streng i ein annan streng. Du kan ĂČg skriva inn kvar sĂžket skal byrja.SĂžkjeordet kan vera eit tal eller ein annan teiknstreng. SĂžket skil mellom store og smĂ„ bokstavar.

Syntaks

FINN("FinnTekst"; "Tekst"[; Plassering])

FinnTekst er teksten som skal finnast. («NÄla»).

Tekst er teksten det skal sÞkjast i. («HÞystakken»).

Plasering (valfri) er posisjonen i teksten som sÞket skal byrja frÄ.

Eksempel

=FINN(76; 998877665544) returnerer 6.

GJENTA (REPT pÄ engelsk)

Denne funksjonen tek opp att ein tekststreng eit visst tal gongar.

Syntaks

GJENTA("Tekst"; Tal)

Tekst er teksten som skal gjentakast.

Tal er talet pÄ gjentakingar.

Eksempel

=GENTA("God morgon";2) returnerer God morgonGod morgon.

tip

SjÄ wikisida REPT for Ä sjÄ meir om denne funksjonen (pÄ engelsk).


HØGRE (RIGHT pÄ engelsk)

Returnerer teikna lengst til hĂžgre i ein tekst.

Syntaks

HØGRE("Tekst" [; Tal])

Tekst er teksten som teikna skal hentast ut frÄ.

Tal (valfri) er talet pÄ kor mange teikn frÄ byrjinga av teksten som skal returnerast. Dersom denne parameteren ikkje er sett, vert det returnert eitt teikn.

Eksempel

=HØGRE("SÞndag";2) returnerer ag.

HØGREB

Returnerer det siste teiknet eller dei siste teikna i ein tekst som brukar dobbelbyte teiknsett (DBCS).

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.


Syntaks

HØGREB("Tekst" [; Tal_byte])

Tekst er teksten som dei hÞgre teikna skal hentast ut frÄ.

Tal_pÄ_byte (valfri) er talet pÄ kor mange teikn HØGREB skal trekkja ut, basert pÄ byte. Dersom denne parameteren ikkje er sett, vert eitt teikn returnert.

Eksempel

HØGREB("äž­ć›œ";1) returnerer « » (1 byte er berre halvparten av eit DBCS-teikn og mellomrom vert returnert i staden).

HØGREB("äž­ć›œ";2) returnerer Â«ć›œÂ» (2 byte er eit fullstendig DBCS-teikn).

HØGREB("äž­ć›œ";3) returnerer « ć›œÂ» (3 byte er eitt og eit halvt DBCS-teikn. Det vert difor returnert eit mellomrom for det fĂžrste halve teiknet).

HØGREB("äž­ć›œ";4) returnnerer Â«äž­ć›œÂ» (4 byte er to fullstendige DBCS-teikn).

HØGEB("office";3) returnerer «ice» (3 ikkje-DBCS-teikn, kvar pÄ 1 byte).

KJEDA.SAMAN (CONCATENATE pÄ engelsk)

SlÄr saman fleire deltekstar til ein samanhengande tekst.

Syntaks

KJEDA.SAMAN(Streng 1[; Streng 2][; 
 ;[Streng 255]])

Streng 1[; Streng 2][; 
 ;[Streng 255]] er strengar eller referansar til celler som inneheld strengar.

Eksempel

=KJEDA.SAMAN("God ";"morgon ";"fru ";"Nordmann") returnerer: God morgon fru Nordmann.

KODE (CODE pÄ engelsk)

Returnerer ein talkode for det fĂžrste teiknet i ein tekststreng.

Syntaks

KODE("Tekst")

Tekst er teksten der koden til det fĂžrste teiknet skal finnast.

Kodar som er stÞrre enn 127 er avhengige av kva for teiknsett du brukar pÄ systemet ditt (for eksempel ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250) og det er difor ikkje sikkert at dei er portable.

Eksempel

=KODE("Hieronymus") returnerer 72, =KODE("hieroglyfisk") returnerer 104.

note

Koden som vert bruk her refererer ikkje til ASCII, men til den teikntabellen som er i bruk.


LENGD (LEN pÄ engelsk)

Returnerer lengda pÄ ein tekststreng medrekna mellomrom.

Syntaks

LENGD("Tekst")

Tekst er teksten som du skal finne lengda til.

Eksempel

=LENGD("God ettermiddag") returnerer 15.

=LENGD(12345,67) returnerer 8.

LENGDB

For teiknsett som brukar to byte for Ä definera eit teikn (DBCS). Returnerer talet pÄ byte som er brukte for Ä laga teikna i ein tekststreng.

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.


Syntaks

LENGDB("Tekst")

Tekst er teksten som du skal finne lengda til.

Eksempel

LENGDB("äž­") returnerer 2 (1 DBCS-teikn inneheld 2 byte).

LENGDB("äž­ć›œ") returnerer 4 (2 DBCS-teikn med 2 byte kvar).

LENGDB("office") returnerer 6 (6 ikkje-DBCS-teikn der kvat teikn inneheld 1 byte).

=LENGDB("God ettermiddag") returnerer 15.

=LENGDB(12345,67) returnerer 8.

MIDB

Returnerer ein tekststreng frÄ ein DBCS-tekst. Parameterane gjev startposisjonen og kor mange teikn som skal returnerast.

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.


Syntaks

MIDTB("Tekst"; Start; Tal_pÄ_byte)

Tekst er teksten som teikna skal hentast frÄ.

Start er posisjonen for det fĂžrste teiknet i strengen du skal hente ut.

Tal_pÄ_byte er kor mange teikn MIDTB skal hente ut frÄ teksten, i byte.

Eksempel

MIDTB("äž­ć›œ";1;0) returnerer «» (0 byte er alltid ein tom streng).

MIDTB("äž­ć›œ";1;1) returnerer « » (1 byte er berre eit halvt DBCS-teikn og resultatet vert difor eit mellomrom).

MIDTB("äž­ć›œ";1;2) returnerer «䞭» (2 byte er eit fullstendig DBCS-teikn).

MIDTB("äž­ć›œ";1;3) returnerer «䞭 » (3 byte er eitt og eit halvt DBCS-teikn. Det siste teiknet er difor eit mellomrom).

MIDTB("äž­ć›œ";1;4) returnnerer Â«äž­ć›œÂ» (4 byte er to fullstendige DBCS-teikn).

MIDTB("äž­ć›œ";2;1) returnerer « » (den 2. byteposisjonen er ikkje i byrjinga av eit teikn i ein DBCS-streng og resultatet vert difor eit mellomrom).

MIDTB("äž­ć›œ";2;2) returnerer « » (den 2. byteposisjonen peikar til den siste halvdelen av det fĂžrste teiknet i ein DBCS-streng. Dei 2 bytane som vert returnerte er difor den siste halvparten av det fĂžrste teiknet og den fĂžrste halvparten av det andre teiknet. Det vert difor returnert 2 mellomrom).

MIDTB("äž­ć›œ";2;3) returnerer « ć›œÂ» (den 2. byteposisjonen er ikkje byrjinga av eit teikn i ein DBCS-streng og resultatet vert difor eit mellomrom for byteposisjon 2).

MIDTB("äž­ć›œ";3;1) returnerer « » (den 3. byteposisjonen er ved byrjinga av eit teikn i ein DBCS-streng, men 1 byte er berre halvparten av eit DBCS-teikn og difor vert det returnert eit mellomrom).

MIDTB("äž­ć›œ";3;2) returnerer Â«ć›œÂ» (den 3. byteposisjonen er ved byrjinga av eit teikn i ein DBCS-streng og 2 byte utgjer eit DBCS-teikn).

MIDTB("kontor";2;3) returnerer «ont» (den 2. byteposisjonen er ved byrjinga av eit teikn i ein ikkje-DBCSstreng og 3 byte av ein ikkje-DBCS-streng utgjer 3 teikn).

MIDT

Returnerer ein tekststreng frÄ ein tekststreng. Parameterane gjev startposisjonen og kor mange teikn.

Syntaks

MIDT("Tekst"; Start; Tal)

Tekst er teksten som teikna skal hentast frÄ.

Start er posisjonen for det fĂžrste teiknet i strengen du skal hente ut.

Tal er kor mange teikn som skal hentast ut.

Eksempel

=MIDT("office";2;2) returnerer ff.

NØYAKTIG (EXACT pÄ engelsk)

Samanliknar to tekststrengar og returnerer SANN om dei er nÞyaktig like, elles USANN. Denne funksjonen skil mellom store og smÄ bokstavar.

Syntaks

NØYAKTIG("Tekst1"; "Tekst2")

Tekst1 er den fĂžrste teksten som skal samanliknast.

Tekst2 er den andre teksten som skal samanliknast.

Eksempel

=NØYAKTIG("microsystems"; "Microsystems") returnerer USANN.

REINSK (CLEAN pÄ engelsk)

Fjernar alle teikn som ikkje kan skrivast ut frÄ strengen.

Syntaks

REINSK("Tekst")

Tekst refererer til teksten som alle teikn som ikkje kan skrivast ut, vert fjerna frÄ.

Eksempel

=LENGD(REINSK(TEIKNKODE(7) & "LibreOffice Calc" & TEIKNKODE(8))) returnerer 16 og viser at funksjonen REINSK fjernar dei ikkje-utskrivbare teikna Unicode U+0007 ("BEL") og U+0008 ("BS") i byrjinga og slutten av strengen. REINSK fjernar ikkje mellomrom.

SMÅ (LOWER pĂ„ engelsk)

Gjer om alle store bokstavar i ein tekst til smÄ bokstavar.

Syntaks

SMÅ("Tekst")

Tekst refererer til teksten som skal konverterast.

Eksempel

=SMÅ("Sola") returnerer sola.

STOR.FORBOKSTAV (PROPER pÄ engelsk)

Skriv den fĂžrste bokstaven i kvart ord i ein tekststreng med stor forbokstav.

Syntaks

STOR.FORBOKSTAV("Tekst")

Tekst refererer til teksten som skal konverterast.

Eksempel

=STOR.FORBOKSTAV("dette er ein tekst") returnerer «Dette Er Ein Tekst».

STORE (UPPER pÄ engelsk)

Gjer om strengen i tekstfeltet til store bokstavar.

Syntaks

STORE("Tekst")

Tekst er teksten med smÄ bokstavar som du vil konvertera til store bokstavar.

Eksempel

=STORE("God morgon") returnerer GOD MORGON.

SØK (SEARCH pÄ engelsk)

Returnerer posisjonen til ein deltekst i ein tekststreng. Du kan setja startposisjonen til sÞket. SÞkjeteksten kan vera eit tal eller ein streng med teikn. SÞket skil ikkje mellom store og smÄ bokstavar. Viss teksten ikkje vart funnen, vert feilmeldinga 519 (#VERDI) vist.

SĂžkinga har stĂžtte for jokerteikn eller regulĂŠre uttrykk. Med regulĂŠre uttrykk slĂ„tt pĂ„, kan du for eksempel skriva inn «all.*» for Ă„ finna den fĂžrste staden som byrjar med «all» med kva teikn som helst etter denne. Viss du skal sĂžkja etter ein tekst som ogsĂ„ er eit regulĂŠrt uttrykk, mĂ„ du anten skriva bakoverstrek (\) framfĂžre kvar operator eller kvart metateikn eller du mĂ„ lukka inn teksten mellom «\Q» og «\E». Du kan slĂ„ den automatiske evalueringa av jokerteikn og regulĂŠre uttrykk av eller pĂ„ frĂ„ i → LibreOffice Calc → Rekn ut.

warning

NÄr du brukar funksjonar der eitt eller fleire argument er sÞkjekriterium som representerer eit regulÊrt uttrykk, vert det fÞrst prÞvd Ä konvertera strengkriteria til tal. For eksempel vert «.0» konvertert til 0.0 og sÄ vidare. Viss dette gÄr bra, vil treffet ikkje vera eit vanleg uttrykk, men eit numerisk treff. NÄr du brukar eit sprÄk som ikkje brukar punktum som desimalskiljeteikn, som i norsk, vil konverteringa av regulÊre uttrykk fungera. For Ä tvinga evalueringa av det regulÊre uttrykket i staden for eit numerisk uttrykk, bruk eit uttrykk som ikkje kan feiltolkast som numerisk, for eksempel «. [0]» eller «". \ 0» eller «(? I) .0».


Syntaks

SØK("FinnTekst"; "Tekst"[; Plassering])

FinnTekst er teksten det skal sĂžkast etter.

Tekst er teksten det skal sĂžkast i.

Plassering (valfri) er plasseringa i teksten som sÞket skal byrje frÄ.

Eksempel

=SØK(54; 998877665544) returnerer 10.

T

Denne funksjonen returnerer mÄlteksten, eller ein tom tekststreng viss mÄlet ikkje er ein tekst.

Syntaks

T(Verdi)

Dersom Verdi er ein tekststreng eller refererer til ein tekststreng, returnerer T denne tekststrengen, ellers returnerer han ein tom tekststreng.

Eksempel

=T(12345) returnerer ein tom streng "".

=T("12345") returnerer strengen 12345.

TEIKNKODE

Gjer om eit tal til eit teikn i samsvar med den kodetabellen som er i bruk. Talet kan vera to- eller tresifra og berre heile tal kan brukast.

Kodar som er stÞrre enn 127 er avhengige av kva for teiknsett du brukar pÄ systemet ditt (for eksempel ISO-8859-1, ISO-8859-2, Windows-1252, Windows-1250) og det er difor ikkje sikkert at dei er portable.

Syntaks

TEIKNKODE(Tal)

Tal er eit heiltal mellom 1 og 255 som representerer talverdien til teiknet.

Eksempel

TEIKNKODE(100) returnerer teiknet d.

="abc" & CHAR(10) & "def" set teiknet for linjeskift inn i strengen.

TEKST (TEXT pÄ engelsk)

Omformar ein verdi til tekst ut frÄ det gjevne formatet.

Syntaks

TEKST(Verdi; Format)

Verdi er den nummeriske verdien eller tekstverdien som skal omformast.

Format er teksten som definerer formatet. Bruk desimal- og tusenskiljeteikn ut frÄ sprÄkinnstillinga i celleformatet.

Eksempel

=TEKST(12,34567;"###,##") returnerer teksten 12,35

=TEKST(12,34567;"000,00")returnerer teksten 012,35

=TEXT("xyz";"=== @ ===") returnerer teksten === xyz ===

tip

SjÄ ogsÄ Talformatkodar: tilpassa formatkodar definert av brukaren.


TRIM

Tar bort ekstra mellomrom frÄ ein streng slik at det berre vert igjen eitt mellomrom mellom ord.

Syntaks

TRIM("Tekst")

Tekst er teksten som mellomromma skal fjernast frÄ.

Eksempel

=TRIM(" hallo......verda ") returnerer «hallo verda» utan mellomrom fÞr og etter, og eitt enkelt mellomrom mellom orda.

UNICODE

Returnerer talkoden for det fĂžrste Unicode-teiknet i ein tekststreng.

Syntaks

UNICODE("Tekst")

Eksempel

=UNICODE("©") returnerer unicodeverdien 169 for copyrightteiknet.

tip

SjÄ ogsÄ UNITEIKN()-funksjonen.


UNITEIKN (UNICHAR pÄ engelsk)

Konverterer ein teiknkode til eit Unicode-teikn eller ein Unicode-bokstav.

Syntaks

UNITEIKN(tal)

Eksempel

=UNITEIKN(169) returnerer opphavsrett-teiknet ©.

tip

SjÄ ogsÄ UNICODE()-funksjonen.


VALUTA (DOLLAR pÄ engelsk)

Konverterer eit tal til ein tekst summen i valutaformatet, avrunda til gjevne desimalplassar ved hjelp av desimalskiljeteiknet som svarar til gjeldande lokale innstillingar. Du skriv inn talet som skal konverterast i feltet Verdi. Du kan eventuelt skriva inn talet pÄ desimalar i feltet Desimalar. Viss det ikkje er gjeve nokon verdi her, vert alle tal viste i valutaformat med to desimalar.

Du bestemmer valutaformatet i systeminnstillingane.

Syntaks

VALUTA(Verdi[; Desimalar})

Verdi er eit tal, ein referanse til ei celle med eit tal eller ein formel som returnerer eit tal.

Desimalar er talet pÄ desimalar.

Eksempel

=VALUTA(255) returnerer $255.00 for den engelske lokaliseringa (USA) og valutaen USD (dollar); ïż„255.00 for den japanske lokalisering og valutaen JPY (yen), 255,00 € for tysk lokalisering (Tyskland) og valutaen EUR (euro) eller kr 255,00 for norsk lokalisering.

=VALUTA(367,456;2) returnerer kr 367,46.

VENSTRE (LEFT pÄ engelsk)

Returnerer det fĂžrste teiknet eller dei fĂžrste teikna i ein tekst.

Syntaks

VENSTRE("Tekst"[; Tal])

Tekst er teksten teikna skal hentast frÄ.

Tal (valfri) er talet pÄ kor mange teikn frÄ byrjinga av teksten som skal returnerast. Dersom denne parameteren ikkje er sett, vert det returnert eitt teikn.

Eksempel

=VENSTRE("utdata"; 3) returnerer «utd».

VENSTREB

Returnerer dei fĂžrste teikna av ein DBCS-tekst.

tip

Denne funksjonen har vore tilgjengeleg sidan LibreOffice 4.2.


Syntaks

VENSTREB("Tekst"[; Tal_pÄ_byte])

Tekst er teksten teikna skal hentast frÄ.

Tal_pÄ_byte (valfri) er talet pÄ kor mange teikn frÄ byrjinga av teksten som skal returnerast, basert pÄ byte. Dersom denne parameteren ikkje er sett, vert eitt teikn returnert.

Eksempel

VENSTREB("äž­ć›œ";1) returnerer « » (1 byte er berre halvparten av eit DBCS-teikn og mellomrom vert returnert i staden).

VENSTREB("äž­ć›œ";2) returnerer «䞭» (2 byte er eit fullstendig DBCS-teikn).

VENSTREB("äž­ć›œ";3) returnerer «䞭 » (3 byte er eitt og eit halvt DBCS-teikn. Det siste teiknet er difor eit mellomrom).

VENSTREB("äž­ć›œ";4) returnnerer Â«äž­ć›œÂ» (4 byte er to fullstendige DBCS-teikn).

VENSTREB("kontor";3) returnerer "kon" (3 ikkje-DBCS-teikn, kvar pÄ 1 byte).